libcomps: add support for python2

libcomps is required by dnf, and the python2 support is needed
after adding python2 support for dnf.

Issue-ID: INF-97
Signed-off-by: Jackie Huang <jackie.huang@windriver.com>
Change-Id: I157ffb471b727736d9a00d4ca2498e9c1f0de8e4

diff --git a/meta-stx/recipes-devtools/libcomps/libcomps_git.bbappend b/meta-stx/recipes-devtools/libcomps/libcomps_git.bbappend
new file mode 100644 (file)
index 0000000..e68a78b
--- /dev/null
+++ b/meta-stx/recipes-devtools/libcomps/libcomps_git.bbappend
@@ -0,0 +1,57 @@
+#
+# Copyright (C) 2019 Wind River Systems, Inc.
+#
+#  Licensed under the Apache License, Version 2.0 (the "License");
+#  you may not use this file except in compliance with the License.
+#  You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+#  Unless required by applicable law or agreed to in writing, software
+#  distributed under the License is distributed on an "AS IS" BASIS,
+#  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+#  See the License for the specific language governing permissions and
+#  limitations under the License.
+
+DEPENDS += "\
+    python-native \
+    "
+
+EXTRA_OECMAKE_PY2 = " \
+    -DPYTHON_DESIRED=2 \
+    -DPYTHON_INSTALL_DIR=${libdir}/python2.7/site-packages \
+    -DPYTHON_EXECUTABLE=${STAGING_BINDIR_NATIVE}/python-native/python \
+    "
+
+do_configure_append() {
+       rm -rf ${B}/build-py2
+       mkdir -p ${B}/build-py2
+       cd ${B}/build-py2
+
+       cmake \
+         ${OECMAKE_GENERATOR_ARGS} \
+         $oecmake_sitefile \
+         ${OECMAKE_SOURCEPATH} \
+         -DCMAKE_INSTALL_PREFIX:PATH=${prefix} \
+         -DCMAKE_INSTALL_SO_NO_EXE=0 \
+         -DCMAKE_TOOLCHAIN_FILE=${WORKDIR}/toolchain.cmake \
+         -DCMAKE_NO_SYSTEM_FROM_IMPORTED=1 \
+         ${EXTRA_OECMAKE_PY2} \
+         -Wno-dev
+}
+
+cmake_runcmake_build_py2() {
+       bbnote ${DESTDIR:+DESTDIR=${DESTDIR} }VERBOSE=1 cmake --build '${B}/build-py2' "$@" -- ${EXTRA_OECMAKE_BUILD}
+       eval ${DESTDIR:+DESTDIR=${DESTDIR} }VERBOSE=1 cmake --build '${B}/build-py2' "$@" -- ${EXTRA_OECMAKE_BUILD}
+}
+
+do_compile_append() {
+       cd ${B}/build-py2
+       cmake_runcmake_build_py2 --target ${OECMAKE_TARGET_COMPILE}
+}
+
+do_install_append() {
+       cd ${B}/build-py2
+       DESTDIR='${D}' cmake_runcmake_build_py2 --target ${OECMAKE_TARGET_INSTALL}
+}
+