meta-starlingx/meta-stx-integ/recipes-support/cluster-glue/cluster-glue_1.0.12.bb

   1
   2 DESCRIPTION = "Cluster Glue is a set of libraries, tools and utilities suitable for \
   3 the Heartbeat/Pacemaker cluster stack. In essence, Glue is everything that \
   4 is not the cluster messaging layer (Heartbeat), nor the cluster resource manager \
   5 (Pacemaker), nor a Resource Agent."
   6 HOMEPAGE = "http://clusterlabs.org/"
   7 LICENSE = "GPLv2 & LGPLv2.1"
   8 LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
   9                     file://COPYING.LIB;md5=243b725d71bb5df4a1e5920b344b86ad \
  10 "
  11
  12 DEPENDS = "libxml2 libtool glib-2.0 bzip2 util-linux net-snmp openhpi"
  13
  14 SRC_URI = " \
  15     http://hg.linux-ha.org/glue/archive/glue-${PV}.tar.bz2 \
  16     file://0001-don-t-compile-doc-and-Error-Fix.patch \
  17     file://0001-ribcl.py.in-Warning-Fix.patch \
  18     file://volatiles \
  19     file://tmpfiles \
  20 "
  21 SRC_URI_append_libc-uclibc = " file://kill-stack-protector.patch"
  22
  23 SRC_URI[md5sum] = "ec620466d6f23affa3b074b72bca7870"
  24 SRC_URI[sha256sum] = "feba102fa1e24b6be2005089ebe362b82d6567af60005cf371679b1b44ec503f"
  25
  26 inherit autotools useradd pkgconfig systemd
  27
  28 SYSTEMD_SERVICE_${PN} = "logd.service"
  29 SYSTEMD_AUTO_ENABLE = "disable"
  30
  31 HA_USER = "hacluster"
  32 HA_GROUP = "haclient"
  33
  34 S = "${WORKDIR}/Reusable-Cluster-Components-glue--glue-${PV}"
  35
  36 PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
  37 PACKAGECONFIG[systemd] = "--with-systemdsystemunitdir=${systemd_system_unitdir},--without-systemdsystemunitdir,systemd"
  38
  39 EXTRA_OECONF = "--with-daemon-user=${HA_USER} \
  40                 --with-daemon-group=${HA_GROUP} \
  41                 --disable-fatal-warnings \
  42                "
  43
  44 CACHED_CONFIGUREVARS="ac_cv_path_XML2CONFIG=0"
  45
  46 USERADD_PACKAGES = "${PN}"
  47 USERADD_PARAM_${PN} = "--home-dir=${localstatedir}/lib/heartbeat/cores/${HA_USER} \
  48                        -g ${HA_GROUP} -r -s ${sbindir}/nologin -c 'cluster user' ${HA_USER} \
  49                       "
  50 GROUPADD_PARAM_${PN} = "-r ${HA_GROUP}"
  51
  52 do_configure_prepend() {
  53     ln -sf ${PKG_CONFIG_SYSROOT_DIR}/usr/include/libxml2/libxml ${PKG_CONFIG_SYSROOT_DIR}/usr/include/libxml
  54 }
  55
  56 do_install_append() {
  57         install -d ${D}${sysconfdir}/default/volatiles
  58         install -m 0644 ${WORKDIR}/volatiles ${D}${sysconfdir}/default/volatiles/04_cluster-glue
  59         install -d ${D}${sysconfdir}/tmpfiles.d
  60         install -m 0644 ${WORKDIR}/tmpfiles ${D}${sysconfdir}/tmpfiles.d/${PN}.conf
  61 }
  62
  63 pkg_postinst_${PN} () {
  64         if [ -z "$D" ]; then
  65                 if type systemd-tmpfiles >/dev/null; then
  66                         systemd-tmpfiles --create
  67                 elif [ -e ${sysconfdir}/init.d/populate-volatile.sh ]; then
  68                         ${sysconfdir}/init.d/populate-volatile.sh update
  69                 fi
  70         fi
  71 }
  72
  73 PACKAGES += "\
  74          ${PN}-plugin-test \
  75          ${PN}-plugin-test-dbg \
  76          ${PN}-plugin-test-staticdev \
  77          ${PN}-plugin-stonith2 \
  78          ${PN}-plugin-stonith2-dbg \
  79          ${PN}-plugin-stonith2-staticdev \
  80          ${PN}-plugin-stonith2-ribcl \
  81          ${PN}-plugin-stonith-external \
  82          ${PN}-plugin-raexec \
  83          ${PN}-plugin-raexec-dbg \
  84          ${PN}-plugin-raexec-staticdev \
  85          ${PN}-plugin-interfacemgr \
  86          ${PN}-plugin-interfacemgr-dbg \
  87          ${PN}-plugin-interfacemgr-staticdev \
  88          ${PN}-lrmtest \
  89          ${PN}-plugin-compress \
  90          ${PN}-plugin-compress-dbg \
  91          ${PN}-plugin-compress-staticdev \
  92          "
  93
  94 FILES_${PN} = "${sysconfdir} /var ${libdir}/lib*.so.* ${sbindir} ${datadir}/cluster-glue/*sh ${datadir}/cluster-glue/*pl\
  95         ${libdir}/heartbeat/transient-test.sh \
  96         ${libdir}/heartbeat/logtest \
  97         ${libdir}/heartbeat/ipctransientserver \
  98         ${libdir}/heartbeat/base64_md5_test \
  99         ${libdir}/heartbeat/ipctest \
 100         ${libdir}/heartbeat/ipctransientclient \
 101         ${libdir}/heartbeat/ha_logd \
 102         ${libdir}/heartbeat/lrmd \
 103         ${systemd_unitdir} \
 104         "
 105
 106 FILES_${PN}-dbg += "${libdir}/heartbeat/.debug/ \
 107                    "
 108 FILES_${PN}-plugin-compress = "${libdir}/heartbeat/plugins/compress/*.so"
 109 FILES_${PN}-plugin-compress-staticdev = "${libdir}/heartbeat/plugins/compress/*.*a"
 110 FILES_${PN}-plugin-compress-dbg = "${libdir}/heartbeat/plugins/compress/.debug/"
 111
 112 FILES_${PN}-plugin-test = "${libdir}/heartbeat/plugins/test/test.so"
 113 FILES_${PN}-plugin-test-staticdev = "${libdir}/heartbeat/plugins/test/test.*a"
 114 FILES_${PN}-plugin-test-dbg = "${libdir}/heartbeat/plugins/test/.debug/"
 115 FILES_${PN}-plugin-stonith2 = " \
 116         ${libdir}/stonith/plugins/xen0-ha-dom0-stonith-helper \
 117         ${libdir}/stonith/plugins/stonith2/*.so \
 118         "
 119 FILES_${PN}-plugin-stonith2-ribcl = "${libdir}/stonith/plugins/stonith2/ribcl.py"
 120
 121 FILES_${PN}-plugin-stonith2-dbg = "${libdir}/stonith/plugins/stonith2/.debug/"
 122 FILES_${PN}-plugin-stonith2-staticdev = "${libdir}/stonith/plugins/stonith2/*.*a"
 123
 124 FILES_${PN}-plugin-stonith-external = "${libdir}/stonith/plugins/external/"
 125 FILES_${PN}-plugin-raexec = "${libdir}/heartbeat/plugins/RAExec/*.so"
 126 FILES_${PN}-plugin-raexec-staticdev = "${libdir}/heartbeat/plugins/RAExec/*.*a"
 127 FILES_${PN}-plugin-raexec-dbg = "${libdir}/heartbeat/plugins/RAExec/.debug/"
 128
 129 FILES_${PN}-plugin-interfacemgr = "${libdir}/heartbeat/plugins/InterfaceMgr/generic.so"
 130 FILES_${PN}-plugin-interfacemgr-staticdev = "${libdir}/heartbeat/plugins/InterfaceMgr/generic.*a"
 131 FILES_${PN}-plugin-interfacemgr-dbg = "${libdir}/heartbeat/plugins/InterfaceMgr/.debug/"
 132
 133 FILES_${PN}-lrmtest = "${datadir}/cluster-glue/lrmtest/"
 134
 135 RDEPENDS_${PN} += "perl"
 136 RDEPENDS_${PN}-plugin-stonith2 += "bash"
 137 RDEPENDS_${PN}-plugin-stonith-external += "bash python perl"
 138 RDEPENDS_${PN}-plugin-stonith2-ribcl += "python"