meta-starlingx/meta-stx-integ/recipes-extended/sudo/sudo_%.bbappend

   1 FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
   2
   3 DEPENDS += " \
   4         openldap \
   5         libgcrypt \
   6         "
   7
   8 inherit stx-metadata
   9
  10 STX_REPO = "config-files"
  11 STX_SUBPATH = "sudo-config"
  12
  13 LICENSE_append = "& Apache-2.0"
  14 LIC_FILES_CHKSUM += "\
  15         file://${STX_METADATA_PATH}/files/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57 \
  16         "
  17
  18 SRC_URI += " \
  19         file://sudo-1.6.7p5-strip.patch \
  20         file://sudo-1.7.2p1-envdebug.patch \
  21         file://sudo-1.8.23-sudoldapconfman.patch \
  22         file://sudo-1.8.23-legacy-group-processing.patch \
  23         file://sudo-1.8.23-ldapsearchuidfix.patch \
  24         file://sudo-1.8.6p7-logsudouser.patch \
  25         file://sudo-1.8.23-nowaitopt.patch \
  26         file://sudo-1.8.23-fix-double-quote-parsing-for-Defaults-values.patch \
  27         "
  28
  29 EXTRA_OECONF += " \
  30         --with-pam-login \
  31         --with-editor=${base_bindir}/vi \
  32         --with-env-editor \
  33         --with-ignore-dot \
  34         --with-tty-tickets \
  35         --with-ldap \
  36         --with-ldap-conf-file="${sysconfdir}/sudo-ldap.conf" \
  37         --with-passprompt="[sudo] password for %Zp: " \
  38         --with-sssd \
  39         "
  40
  41 do_install_append () {
  42         install -m755 -d ${D}/${sysconfdir}/openldap/schema
  43         install -m644 ${S}/doc/schema.OpenLDAP  ${D}/${sysconfdir}/openldap/schema/sudo.schema
  44         install -m 440 ${STX_METADATA_PATH}/files/sysadmin.sudo  ${D}/${sysconfdir}/sudoers.d/sysadmin
  45 }
  46
  47 # This means sudo package only owns files
  48 # to avoid install conflict with openldap on
  49 # /etc/openldap. Sure there is a better way.
  50 DIRFILES = "1"