meta-starlingx/meta-stx-integ/recipes-devtools/libdnf/libdnf_0.26.0.bbappend

   1 DEPENDS += "\
   2     python-native \
   3     "
   4
   5 EXTRA_OECMAKE_PY2 = " \
   6     -DPYTHON_INSTALL_DIR=${libdir}/python2.7/site-packages \
   7     -DPYTHON_DESIRED:FILEPATH=${STAGING_BINDIR_NATIVE}/python-native/python \
   8     -DWITH_MAN=OFF \
   9     ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DWITH_GIR=ON', '-DWITH_GIR=OFF', d)} \
  10     -DWITH_TESTS=OFF \
  11     "
  12
  13 do_configure_append() {
  14         rm -rf ${B}/build-py2
  15         mkdir -p ${B}/build-py2
  16         cd ${B}/build-py2
  17
  18         cmake \
  19           ${OECMAKE_GENERATOR_ARGS} \
  20           $oecmake_sitefile \
  21           ${OECMAKE_SOURCEPATH} \
  22           -DCMAKE_INSTALL_PREFIX:PATH=${prefix} \
  23           -DCMAKE_INSTALL_SYSCONFDIR:PATH=${sysconfdir} \
  24           -DCMAKE_INSTALL_SO_NO_EXE=0 \
  25           -DCMAKE_TOOLCHAIN_FILE=${WORKDIR}/toolchain.cmake \
  26           -DCMAKE_NO_SYSTEM_FROM_IMPORTED=1 \
  27           ${EXTRA_OECMAKE_PY2} \
  28           -Wno-dev
  29 }
  30
  31 cmake_runcmake_build_py2() {
  32         bbnote ${DESTDIR:+DESTDIR=${DESTDIR} }VERBOSE=1 cmake --build '${B}/build-py2' "$@" -- ${EXTRA_OECMAKE_BUILD}
  33         eval ${DESTDIR:+DESTDIR=${DESTDIR} }VERBOSE=1 cmake --build '${B}/build-py2' "$@" -- ${EXTRA_OECMAKE_BUILD}
  34 }
  35
  36 do_compile_append() {
  37         cd ${B}/build-py2
  38         cmake_runcmake_build_py2 --target ${OECMAKE_TARGET_COMPILE}
  39 }
  40
  41 do_install_append() {
  42         cd ${B}/build-py2
  43         DESTDIR='${D}' cmake_runcmake_build_py2 --target ${OECMAKE_TARGET_INSTALL}
  44 }
  45