meta-starlingx/meta-stx-flock/stx-openstack-armada-app/openstack-helm-infra_1.0.bb

   1
   2 SUMMARY = "Openstack-Helm-Infra charts"
   3 DESCRIPTION = "Openstack-Helm-Infra charts"
   4
   5 LICENSE = "Apache-2.0"
   6 LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
   7
   8 DEPENDS += "helm-native"
   9
  10 PROTOCOL = "https"
  11 BRANCH = "r/stx.3.0"
  12 SRCREV_openstack-helm-infra = "c9d6676bf9a5aceb311dc31dadd07cba6a3d6392"
  13 SRCREV_openstack-armada-app = "863f4b9733d3d4f4fd490606a94b84cfdaf2df2c"
  14
  15 # Patches pulled from:
  16 # SRCREV_openstack-armada-app = "863f4b9733d3d4f4fd490606a94b84cfdaf2df2c"
  17 # git://opendev.org/starlingx/openstack-armada-app
  18
  19 SRC_URI = " \
  20     git://github.com/openstack/openstack-helm-infra;protocol=${PROTOCOL};name=openstack-helm-infra \
  21     file://0001-Allow-multiple-containers-per-daemonset-pod.patch \
  22     file://0002-Add-imagePullSecrets-in-service-account.patch \
  23     file://0003-Set-Min-NGINX-handles.patch \
  24     file://0004-Partial-revert-of-31e3469d28858d7b5eb6355e88b6f49fd6.patch \
  25     file://0005-Add-TLS-support-for-Gnocchi-public-endpoint.patch \
  26     file://0006-Fix-pod-restarts-on-all-workers-when-worker-added-re.patch \
  27     file://0007-Add-io_thread_pool-for-rabbitmq.patch \
  28     file://0008-Enable-override-of-rabbitmq-probe-parameters.patch \
  29     file://repositories.yaml \
  30     "
  31
  32 PATCHTOOL = "git"
  33 PATCH_COMMIT_FUNCTIONS = "1"
  34
  35 S = "${WORKDIR}/git"
  36
  37 inherit allarch
  38
  39 helm_folder = "${nonarch_libdir}/helm"
  40
  41 do_configure[noexec] = "1"
  42
  43 do_compile () {
  44         # initialize helm and build the toolkit
  45         # helm init --client-only does not work if there is no networking
  46         # The following commands do essentially the same as: helm init
  47         export HOME="${B}/${USER}"
  48         export helm_home="${B}/${USER}/.helm"
  49         rm -rf ${helm_home}
  50
  51         mkdir -p ${helm_home}
  52         mkdir ${helm_home}/repository
  53         mkdir ${helm_home}/repository/cache
  54         mkdir ${helm_home}/repository/local
  55         mkdir ${helm_home}/plugins
  56         mkdir ${helm_home}/starters
  57         mkdir ${helm_home}/cache
  58         mkdir ${helm_home}/cache/archive
  59
  60         # Stage a repository file that only has a local repo
  61         install -m 0644 ${WORKDIR}/repositories.yaml \
  62                 ${helm_home}/repository/repositories.yaml
  63
  64         # Host a server for the charts
  65         tmpdir=`mktemp -d ${B}/charts-XXXXXX`
  66         helm serve ${tmpdir} --address localhost:8879 --url http://localhost:8879/charts &
  67         sleep 1
  68         helm repo rm local
  69         helm repo add local http://localhost:8879/charts
  70
  71         # Make the charts. These produce tgz files
  72         make helm-toolkit
  73         make gnocchi
  74         make ingress
  75         make libvirt
  76         make mariadb
  77         make memcached
  78         make openvswitch
  79         make rabbitmq
  80         make ceph-rgw
  81
  82         # terminate helm server (the last backgrounded task)
  83         kill $!
  84         rm -rf ${helm_home}
  85 }
  86
  87 do_install () {
  88         install -d -m 755 ${D}${helm_folder}
  89         install -p -D -m 755 ${B}/*.tgz ${D}${helm_folder}
  90 }
  91
  92 FILES_${PN} = "${helm_folder}"
  93
  94 RDEPENDS_${PN} = "helm"