meta-starlingx/meta-stx-cloud/recipes-extended/registry-token-server/registry-token-server_1.0.0.bb

   1
   2 DESCRIPTION = " Token server for use with Docker registry with Openstack Keystone back end"
   3 LICENSE = "Apache-2.0"
   4 LIC_FILES_CHKSUM = "file://LICENSE;md5=d2794c0df5b907fdace235a619d80314"
   5
   6 GO_IMPORT = "registry-token-server"
   7
   8 SRC_URI = "file://registry-token-server-1.0.0.tar.gz \
   9            file://registry-token-server.service \
  10            file://token_server.conf \
  11           "
  12
  13 RDEPENDS_${PN}-dev_append = "systemd"
  14
  15 DEPENDS += "\
  16         go-logrus \
  17         docker-distribution \
  18         go-libtrust \
  19         go-patricia \
  20         go-mux \
  21         go-context \
  22         go-phercloud \
  23         "
  24
  25 inherit go goarch ${@bb.utils.contains('VIRTUAL-RUNTIME_init_manager','systemd','systemd','', d)}
  26
  27 do_compile() {
  28         mkdir -p _build/src
  29         ln -sfn ${WORKDIR}/${PN}-${PV} ./_build/src/registry-token-server
  30
  31         # Pass the needed cflags/ldflags so that cgo
  32         # can find the needed headers files and libraries
  33         export GOARCH=${TARGET_GOARCH}
  34         export CGO_ENABLED="1"
  35         export CGO_CFLAGS="${CFLAGS} --sysroot=${STAGING_DIR_TARGET}"
  36         export CGO_LDFLAGS="${LDFLAGS} --sysroot=${STAGING_DIR_TARGET}"
  37
  38         export GOPATH="${WORKDIR}/build/_build:${STAGING_DIR_TARGET}/${prefix}/local/go"
  39         cd _build/src/${GO_IMPORT}
  40         #oe_runmake registry-token-server
  41         export GOROOT=${STAGING_DIR_TARGET}/${prefix}/local/go
  42         go build -o ${WORKDIR}/build/bin/registry-token-server registry-token-server
  43 }
  44
  45 SYSTEMD_PACKAGES = "${PN}"
  46 SYSTEMD_SERVICE_${PN} = "registry-token-server.service"
  47 SYSTEMD_AUTO_ENABLE = "enable"
  48
  49 do_install() {
  50         install -d ${D}/${sbindir}
  51         install -m 0755 bin/registry-token-server ${D}/${sbindir}
  52         install -d ${D}/${sysconfdir}/registry-token-server/registry
  53         install -m 0644 ${WORKDIR}/token_server.conf ${D}/${sysconfdir}/registry-token-server/registry
  54
  55         if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
  56             install -d ${D}${systemd_unitdir}/system
  57             install -m 0644 ${WORKDIR}/registry-token-server.service ${D}${systemd_unitdir}/system/
  58         fi
  59 }
  60