otf-camunda/mvnw.cmd

   1 @REM ----------------------------------------------------------------------------\r
   2 @REM Licensed to the Apache Software Foundation (ASF) under one\r
   3 @REM or more contributor license agreements.  See the NOTICE file\r
   4 @REM distributed with this work for additional information\r
   5 @REM regarding copyright ownership.  The ASF licenses this file\r
   6 @REM to you under the Apache License, Version 2.0 (the\r
   7 @REM "License"); you may not use this file except in compliance\r
   8 @REM with the License.  You may obtain a copy of the License at\r
   9 @REM\r
  10 @REM    http://www.apache.org/licenses/LICENSE-2.0\r
  11 @REM\r
  12 @REM Unless required by applicable law or agreed to in writing,\r
  13 @REM software distributed under the License is distributed on an\r
  14 @REM "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY\r
  15 @REM KIND, either express or implied.  See the License for the\r
  16 @REM specific language governing permissions and limitations\r
  17 @REM under the License.\r
  18 @REM ----------------------------------------------------------------------------\r
  19 \r
  20 @REM ----------------------------------------------------------------------------\r
  21 @REM Maven2 Start Up Batch script\r
  22 @REM\r
  23 @REM Required ENV vars:\r
  24 @REM JAVA_HOME - location of a JDK home dir\r
  25 @REM\r
  26 @REM Optional ENV vars\r
  27 @REM M2_HOME - location of maven2's installed home dir\r
  28 @REM MAVEN_BATCH_ECHO - set to 'on' to enable the echoing of the batch commands\r
  29 @REM MAVEN_BATCH_PAUSE - set to 'on' to wait for a key stroke before ending\r
  30 @REM MAVEN_OPTS - parameters passed to the Java VM when running Maven\r
  31 @REM     e.g. to debug Maven itself, use\r
  32 @REM set MAVEN_OPTS=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000\r
  33 @REM MAVEN_SKIP_RC - flag to disable loading of mavenrc files\r
  34 @REM ----------------------------------------------------------------------------\r
  35 \r
  36 @REM Begin all REM lines with '@' in case MAVEN_BATCH_ECHO is 'on'\r
  37 @echo off\r
  38 @REM enable echoing my setting MAVEN_BATCH_ECHO to 'on'\r
  39 @if "%MAVEN_BATCH_ECHO%" == "on"  echo %MAVEN_BATCH_ECHO%\r
  40 \r
  41 @REM set %HOME% to equivalent of $HOME\r
  42 if "%HOME%" == "" (set "HOME=%HOMEDRIVE%%HOMEPATH%")\r
  43 \r
  44 @REM Execute a user defined script before this one\r
  45 if not "%MAVEN_SKIP_RC%" == "" goto skipRcPre\r
  46 @REM check for pre script, once with legacy .bat ending and once with .cmd ending\r
  47 if exist "%HOME%\mavenrc_pre.bat" call "%HOME%\mavenrc_pre.bat"\r
  48 if exist "%HOME%\mavenrc_pre.cmd" call "%HOME%\mavenrc_pre.cmd"\r
  49 :skipRcPre\r
  50 \r
  51 @setlocal\r
  52 \r
  53 set ERROR_CODE=0\r
  54 \r
  55 @REM To isolate internal variables from possible post scripts, we use another setlocal\r
  56 @setlocal\r
  57 \r
  58 @REM ==== START VALIDATION ====\r
  59 if not "%JAVA_HOME%" == "" goto OkJHome\r
  60 \r
  61 echo.\r
  62 echo Error: JAVA_HOME not found in your environment. >&2\r
  63 echo Please set the JAVA_HOME variable in your environment to match the >&2\r
  64 echo location of your Java installation. >&2\r
  65 echo.\r
  66 goto error\r
  67 \r
  68 :OkJHome\r
  69 if exist "%JAVA_HOME%\bin\java.exe" goto init\r
  70 \r
  71 echo.\r
  72 echo Error: JAVA_HOME is set to an invalid directory. >&2\r
  73 echo JAVA_HOME = "%JAVA_HOME%" >&2\r
  74 echo Please set the JAVA_HOME variable in your environment to match the >&2\r
  75 echo location of your Java installation. >&2\r
  76 echo.\r
  77 goto error\r
  78 \r
  79 @REM ==== END VALIDATION ====\r
  80 \r
  81 :init\r
  82 \r
  83 @REM Find the project base dir, i.e. the directory that contains the folder ".mvn".\r
  84 @REM Fallback to current working directory if not found.\r
  85 \r
  86 set MAVEN_PROJECTBASEDIR=%MAVEN_BASEDIR%\r
  87 IF NOT "%MAVEN_PROJECTBASEDIR%"=="" goto endDetectBaseDir\r
  88 \r
  89 set EXEC_DIR=%CD%\r
  90 set WDIR=%EXEC_DIR%\r
  91 :findBaseDir\r
  92 IF EXIST "%WDIR%"\.mvn goto baseDirFound\r
  93 cd ..\r
  94 IF "%WDIR%"=="%CD%" goto baseDirNotFound\r
  95 set WDIR=%CD%\r
  96 goto findBaseDir\r
  97 \r
  98 :baseDirFound\r
  99 set MAVEN_PROJECTBASEDIR=%WDIR%\r
 100 cd "%EXEC_DIR%"\r
 101 goto endDetectBaseDir\r
 102 \r
 103 :baseDirNotFound\r
 104 set MAVEN_PROJECTBASEDIR=%EXEC_DIR%\r
 105 cd "%EXEC_DIR%"\r
 106 \r
 107 :endDetectBaseDir\r
 108 \r
 109 IF NOT EXIST "%MAVEN_PROJECTBASEDIR%\.mvn\jvm.config" goto endReadAdditionalConfig\r
 110 \r
 111 @setlocal EnableExtensions EnableDelayedExpansion\r
 112 for /F "usebackq delims=" %%a in ("%MAVEN_PROJECTBASEDIR%\.mvn\jvm.config") do set JVM_CONFIG_MAVEN_PROPS=!JVM_CONFIG_MAVEN_PROPS! %%a\r
 113 @endlocal & set JVM_CONFIG_MAVEN_PROPS=%JVM_CONFIG_MAVEN_PROPS%\r
 114 \r
 115 :endReadAdditionalConfig\r
 116 \r
 117 SET MAVEN_JAVA_EXE="%JAVA_HOME%\bin\java.exe"\r
 118 \r
 119 set WRAPPER_JAR="%MAVEN_PROJECTBASEDIR%\.mvn\wrapper\maven-wrapper.jar"\r
 120 set WRAPPER_LAUNCHER=org.apache.maven.wrapper.MavenWrapperMain\r
 121 \r
 122 %MAVEN_JAVA_EXE% %JVM_CONFIG_MAVEN_PROPS% %MAVEN_OPTS% %MAVEN_DEBUG_OPTS% -classpath %WRAPPER_JAR% "-Dmaven.multiModuleProjectDirectory=%MAVEN_PROJECTBASEDIR%" %WRAPPER_LAUNCHER% %MAVEN_CONFIG% %*\r
 123 if ERRORLEVEL 1 goto error\r
 124 goto end\r
 125 \r
 126 :error\r
 127 set ERROR_CODE=1\r
 128 \r
 129 :end\r
 130 @endlocal & set ERROR_CODE=%ERROR_CODE%\r
 131 \r
 132 if not "%MAVEN_SKIP_RC%" == "" goto skipRcPost\r
 133 @REM check for post script, once with legacy .bat ending and once with .cmd ending\r
 134 if exist "%HOME%\mavenrc_post.bat" call "%HOME%\mavenrc_post.bat"\r
 135 if exist "%HOME%\mavenrc_post.cmd" call "%HOME%\mavenrc_post.cmd"\r
 136 :skipRcPost\r
 137 \r
 138 @REM pause the script if MAVEN_BATCH_PAUSE is set to 'on'\r
 139 if "%MAVEN_BATCH_PAUSE%" == "on" pause\r
 140 \r
 141 if "%MAVEN_TERMINATE_CMD%" == "on" exit %ERROR_CODE%\r
 142 \r
 143 exit /B %ERROR_CODE%\r