src/ftacmp/partn.y

   1 /* ------------------------------------------------
   2 Copyright 2014 AT&T Intellectual Property
   3    Licensed under the Apache License, Version 2.0 (the "License");
   4    you may not use this file except in compliance with the License.
   5    You may obtain a copy of the License at
   6
   7      http://www.apache.org/licenses/LICENSE-2.0
   8
   9    Unless required by applicable law or agreed to in writing, software
  10    distributed under the License is distributed on an "AS IS" BASIS,
  11    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12    See the License for the specific language governing permissions and
  13    limitations under the License.
  14  ------------------------------------------- */
  15
  16 /*
  17         MUST COMPILE WITH
  18    bison --verbose --defines=partn.tab.cc.h -p PartnParser  -o partn.tab.cc partn.y
  19
  20          (or equivalent).
  21 */
  22
  23 %{
  24
  25
  26 #include <stdio.h>
  27
  28 /*              Some addn'l includes, necessary but not included by the
  29                 bison generated code.
  30 */
  31
  32 #include <stdlib.h>
  33
  34 /*              prototypes for the parser callbacks.
  35 */
  36
  37 #include "parse_partn.h"
  38
  39 extern partn_def_list_t *partn_parse_result;
  40
  41
  42 #define YYDEBUG 1
  43
  44 %}
  45
  46
  47         /* symbolic tokens */
  48
  49 %union {
  50         int intval;
  51         double floatval;
  52         char *strval;
  53         int subtok;
  54
  55 /*                      for FTA definition.     */
  56         literal_t *litval;
  57         scalarexp_t *scalarval;
  58         se_list_t *se_listval;
  59         colref_t *colref;
  60         partn_def_list_t *pdl;
  61         partn_def_t *pd;
  62 }
  63
  64 %token <strval> NAME
  65 %token <strval> STRING_TOKEN
  66 %token <strval> INTNUM
  67 %token <strval> LONGINTNUM
  68
  69 /*                      for FTA definition.     */
  70 %type <litval> literal
  71 %type <colref> column_ref
  72 %type <scalarval> scalar_exp
  73 %type <se_listval> scalar_exp_commalist
  74 %type <pdl> partn_def_list
  75 %type <pd> partn_def
  76
  77 %left '|'
  78 %left '&'
  79 %left '+' '-'
  80 %left '*' '/'
  81 %nonassoc UMINUS
  82
  83         /* literal keyword tokens */
  84 %token HEX_L LHEX_L IP_L
  85
  86
  87 %%
  88
  89 /*                      Union of possible results       */
  90 parse_result:   partn_def_list  {
  91                 partn_parse_result = $1;
  92         }
  93         ;
  94
  95
  96 partn_def_list:
  97         partn_def       {$$ = new partn_def_list_t($1);}
  98         | partn_def_list partn_def      {$$=$1->append($2);}
  99         ;
 100
 101 partn_def:
 102         NAME '[' NAME ']' ':' '(' scalar_exp_commalist ')'
 103                 {$$ = new partn_def_t($1,$3,$7);}
 104         ;
 105
 106 scalar_exp:
 107                 scalar_exp '+' scalar_exp       { $$=new scalarexp_t("+",$1,$3);}
 108         |       scalar_exp '-' scalar_exp       { $$=new scalarexp_t("-",$1,$3);}
 109         |       scalar_exp '|' scalar_exp       { $$=new scalarexp_t("|",$1,$3);}
 110         |       scalar_exp '*' scalar_exp       { $$=new scalarexp_t("*",$1,$3);}
 111         |       scalar_exp '/' scalar_exp       { $$=new scalarexp_t("/",$1,$3);}
 112         |       scalar_exp '&' scalar_exp       { $$=new scalarexp_t("&",$1,$3);}
 113         |       '+' scalar_exp %prec UMINUS     { $$ = new scalarexp_t("+",$2);}
 114         |       '-' scalar_exp %prec UMINUS     { $$ = new scalarexp_t("-",$2);}
 115         |       literal { $$= new scalarexp_t($1);}
 116         |       column_ref { $$ = new scalarexp_t($1);}
 117         |       '(' scalar_exp ')'      {$$ = $2;}
 118         ;
 119
 120 scalar_exp_commalist:
 121                 scalar_exp      {       $$= new se_list_t($1); }
 122         |       scalar_exp_commalist ',' scalar_exp     { $$=$1->append($3); }
 123         ;
 124
 125 literal:
 126                 INTNUM          {$$ = new literal_t($1,LITERAL_INT);}
 127         |       LONGINTNUM              {$$ = new literal_t($1,LITERAL_LONGINT);}
 128         |       HEX_L  STRING_TOKEN     {$$ = new literal_t($2,LITERAL_HEX);}
 129         |       LHEX_L  STRING_TOKEN    {$$ = new literal_t($2,LITERAL_LONGHEX);}
 130         |       IP_L  STRING_TOKEN      {$$ = new literal_t($2,LITERAL_IP);}
 131         ;
 132
 133
 134 column_ref:
 135                 NAME    {$$ = new colref_t($1); }
 136         ;
 137
 138
 139 %%
 140