meta-stx/recipes-support/boost/boost_1.69.0.bbappend

   1 #
   2 ## Copyright (C) 2019 Wind River Systems, Inc.
   3 #
   4 #  Licensed under the Apache License, Version 2.0 (the "License");
   5 #  you may not use this file except in compliance with the License.
   6 #  You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 #  Unless required by applicable law or agreed to in writing, software
  11 #  distributed under the License is distributed on an "AS IS" BASIS,
  12 #  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 #  See the License for the specific language governing permissions and
  14 #  limitations under the License.
  15
  16 DEP_PYTHON = "\
  17     python \
  18     python-native \
  19     python-numpy-native \
  20     python3 \
  21     python3-native \
  22     python3-numpy-native \
  23 "
  24
  25 PACKAGECONFIG = "locale python"
  26 PACKAGECONFIG[python] = ",,${DEP_PYTHON}"
  27
  28 BJAM_OPTS += "${@bb.utils.contains('BOOST_LIBS', 'python', 'python=${PYTHON_BASEVERSION},2.7', '', d)}"
  29
  30 do_configure_append () {
  31     if ${@bb.utils.contains('BOOST_LIBS', 'python', 'true', 'false', d)}; then
  32         echo "using python : 2.7 : ${STAGING_BINDIR_NATIVE}/python-native/python : ${STAGING_INCDIR}/python2.7 : ${STAGING_LIBDIR}/python2.7 ;" >> ${WORKDIR}/user-config.jam
  33         sed -i -e 's|${STAGING_DIR_HOST}${bindir}/python3|${STAGING_BINDIR_NATIVE}/python3-native/python3|' ${WORKDIR}/user-config.jam
  34     fi
  35 }
  36
  37 PACKAGES += "${PN}-python3"
  38
  39 FILES_${PN}-python = " \
  40     ${libdir}/libboost_python2*.so.* \
  41     ${libdir}/libboost_numpy2*.so.* \
  42 "
  43 FILES_${PN}-python3 = " \
  44     ${libdir}/libboost_python3*.so.* \
  45     ${libdir}/libboost_numpy3*.so.* \
  46 "