meta-stx/classes/stx-anaconda-image.bbclass

   1 #
   2 ## Copyright (C) 2019 Wind River Systems, Inc.
   3 #
   4 #  Licensed under the Apache License, Version 2.0 (the "License");
   5 #  you may not use this file except in compliance with the License.
   6 #  You may obtain a copy of the License at
   7 #
   8 #      http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 #  Unless required by applicable law or agreed to in writing, software
  11 #  distributed under the License is distributed on an "AS IS" BASIS,
  12 #  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 #  See the License for the specific language governing permissions and
  14 #  limitations under the License.
  15
  16 RPM_POSTPROCESS_COMMANDS_append = "wrl_installer;"
  17 do_rootfs[vardeps] += "INSTALLER_TARGET_BUILD INSTALLER_TARGET_IMAGE"
  18
  19 # Fix system-shutdown hang at ratelimiting
  20 APPEND_append = " printk.devkmsg=on"
  21
  22 INSTPRODUCT ?= "${DISTRO_NAME}"
  23 INSTVER     ?= "${DISTRO_VERSION}"
  24 INSTBUGURL  ?= "http://www.windriver.com/"
  25
  26 # NOTE: Please update anaconda-init when you change INSTALLER_CONFDIR, use "="
  27 #       but not "?=" since this is not configurable.
  28 INSTALLER_CONFDIR = "${IMAGE_ROOTFS}/installer-config"
  29 KICKSTART_FILE ??= ""
  30 KICKSTART_FILE_EXTRA ??= ""
  31 WRL_INSTALLER_CONF ?= ""
  32 REPO_INCLUDE_PKG ??= ""
  33 REPO_EXCLUDE_PKG ?= ""
  34
  35 build_iso_prepend() {
  36         install -d ${ISODIR}
  37         ln -snf /.discinfo ${ISODIR}/.discinfo
  38         ln -snf /.buildstamp ${ISODIR}/.buildstamp
  39         ln -snf /Packages ${ISODIR}/Packages
  40 }
  41
  42 build_iso_append() {
  43         implantisomd5 ${IMGDEPLOYDIR}/${IMAGE_NAME}.iso
  44 }
  45
  46 # Check WRL_INSTALLER_CONF and copy it to
  47 # ${IMAGE_ROOTFS}/.buildstamp.$prj_name when exists
  48 wrl_installer_copy_buildstamp() {
  49     prj_name=$1
  50     buildstamp=$2
  51     if [ -f $buildstamp ]; then
  52         bbnote "Using $buildstamp as the buildstamp"
  53         cp $buildstamp ${IMAGE_ROOTFS}/.buildstamp.$prj_name
  54     else
  55         bbfatal "Can't find WRL_INSTALLER_CONF: $buildstamp"
  56     fi
  57 }
  58
  59 # Hardlink when possible, otherwise copy.
  60 # $1: src
  61 # $2: target
  62 wrl_installer_hardlinktree() {
  63     src_dev="`stat -c %d $1`"
  64     if [ -e "$2" ]; then
  65         tgt_dev="`stat -c %d $2`"
  66     else
  67         tgt_dev="`stat -c %d $(dirname $2)`"
  68     fi
  69     hdlink=""
  70     if [ "$src_dev" = "$tgt_dev" ]; then
  71         hdlink="--link"
  72     fi
  73     cp -rvf $hdlink $1 $2
  74 }
  75
  76 wrl_installer_copy_local_repos() {
  77     deploy_dir_rpm=$1
  78
  79     if [ -d "$deploy_dir_rpm" ]; then
  80         echo "Copy rpms from target build to installer image."
  81         mkdir -p ${IMAGE_ROOTFS}/Packages.$prj_name
  82
  83         : > ${IMAGE_ROOTFS}/Packages.$prj_name/.treeinfo
  84         echo "[general]" >> ${IMAGE_ROOTFS}/Packages.$prj_name/.treeinfo
  85         echo "version = ${DISTRO_VERSION}" >> ${IMAGE_ROOTFS}/Packages.$prj_name/.treeinfo
  86
  87         # Determine the max channel priority
  88         channel_priority=5
  89         for pt in $installer_target_archs ; do
  90             channel_priority=$(expr $channel_priority + 5)
  91         done
  92
  93         : > ${IMAGE_ROOTFS}/Packages.$prj_name/.feedpriority
  94         for arch in $installer_target_archs; do
  95             if [ -d "$deploy_dir_rpm/"$arch -a ! -d "${IMAGE_ROOTFS}/Packages.$prj_name/"$arch ]; then
  96                 channel_priority=$(expr $channel_priority - 5)
  97                 echo "$channel_priority $arch" >> ${IMAGE_ROOTFS}/Packages.$prj_name/.feedpriority
  98             fi
  99         done
 100
 101         cd ${deploy_dir_rpm}
 102         for pkg in `cat ${REPO_INCLUDE_PKG}`; do
 103             cp --parents -vf */${pkg}.rpm ${IMAGE_ROOTFS}/Packages.$prj_name/
 104         done
 105         cd -
 106
 107         for pkg in ${REPO_EXCLUDE_PKG}; do
 108             rm -rf ${IMAGE_ROOTFS}/Packages.$prj_name/${pkg}
 109         done
 110
 111         createrepo_c --update -q ${IMAGE_ROOTFS}/Packages.$prj_name/
 112     fi
 113 }
 114
 115 # Update .buildstamp and copy rpm packages to IMAGE_ROOTFS
 116 wrl_installer_copy_pkgs() {
 117
 118     target_build="$1"
 119     target_image="$2"
 120     prj_name="$3"
 121     if [ -n "$4" ]; then
 122         installer_conf="$4"
 123     else
 124         installer_conf=""
 125     fi
 126
 127     common_grep="-e '^ALL_MULTILIB_PACKAGE_ARCHS=.*' \
 128             -e '^MULTILIB_VARIANTS=.*' -e '^PACKAGE_ARCHS=.*'\
 129             -e '^PACKAGE_ARCH=.*' -e '^PACKAGE_INSTALL_ATTEMPTONLY=.*' \
 130             -e '^DISTRO=.*' -e '^DISTRO_NAME=.*' -e '^DISTRO_VERSION=.*' \
 131             "
 132
 133     if [ -f "$installer_conf" ]; then
 134         eval "grep -e \"^PACKAGE_INSTALL=.*\" $common_grep $installer_conf \
 135             | sed -e 's/=/=\"/' -e 's/$/\"/' > ${BB_LOGFILE}.distro_vals"
 136
 137         eval "cat $target_build/installersupport_$target_image | \
 138             grep -e '^WORKDIR=.*' >> ${BB_LOGFILE}.distro_vals"
 139
 140         eval `cat ${BB_LOGFILE}.distro_vals`
 141         if [ $? -ne 0 ]; then
 142             bbfatal "Something is wrong in $installer_conf, please correct it"
 143         fi
 144         if [ -z "$PACKAGE_ARCHS" -o -z "$PACKAGE_INSTALL" ]; then
 145             bbfatal "PACKAGE_ARCHS or PACKAGE_INSTALL is null, please check $installer_conf"
 146         fi
 147     else
 148         eval "cat $target_build/installersupport_$target_image | \
 149             grep $common_grep -e '^PN=.*' -e '^SUMMARY=.*' -e '^WORKDIR=.*'\
 150             -e '^DESCRIPTION=.*' -e '^export PACKAGE_INSTALL=.*' > ${BB_LOGFILE}.distro_vals"
 151
 152         eval `cat ${BB_LOGFILE}.distro_vals`
 153     fi
 154
 155     export installer_default_arch="$PACKAGE_ARCH"
 156     # Reverse it for priority
 157     export installer_default_archs="`for arch in $PACKAGE_ARCHS; do echo $arch; done | tac | tr - _`"
 158     installer_target_archs="$installer_default_archs"
 159     if [ -n "$MULTILIB_VARIANTS" ]; then
 160         export MULTILIB_VARIANTS
 161         mlarchs_reversed="`for mlarch in $ALL_MULTILIB_PACKAGE_ARCHS; do echo $mlarch; \
 162             done | tac | tr - _`"
 163         for arch in $mlarchs_reversed; do
 164             if [ "$arch" != "noarch" -a "$arch" != "all" -a "$arch" != "any" ]; then
 165                 installer_target_archs="$installer_target_archs $arch"
 166             fi
 167         done
 168     fi
 169     export installer_target_archs
 170
 171     # Save the vars to .buildstamp when no installer_conf
 172     if [ ! -f "$installer_conf" ]; then
 173         cat >> ${IMAGE_ROOTFS}/.buildstamp.$prj_name <<_EOF
 174 DISTRO=$DISTRO
 175 DISTRO_NAME=$DISTRO_NAME
 176 DISTRO_VERSION=$DISTRO_VERSION
 177
 178 [Rootfs]
 179 LIST=$PN
 180
 181 [$PN]
 182 SUMMARY=$SUMMARY
 183 DESCRIPTION=$DESCRIPTION
 184
 185 PACKAGE_INSTALL=$PACKAGE_INSTALL
 186 PACKAGE_INSTALL_ATTEMPTONLY=$PACKAGE_INSTALL_ATTEMPTONLY
 187 ALL_MULTILIB_PACKAGE_ARCHS=$ALL_MULTILIB_PACKAGE_ARCHS
 188 MULTILIB_VARIANTS=$MULTILIB_VARIANTS
 189 PACKAGE_ARCHS=$PACKAGE_ARCHS
 190 PACKAGE_ARCH=$PACKAGE_ARCH
 191 IMAGE_LINGUAS=${IMAGE_LINGUAS}
 192 _EOF
 193     fi
 194
 195     if [ -d "$WORKDIR/oe-rootfs-repo/rpm" ]; then
 196         # Copy local repos while the image is not initramfs
 197         bpn=${BPN}
 198         if [ "${bpn##*initramfs}" = "${bpn%%initramfs*}" ]; then
 199             wrl_installer_copy_local_repos $WORKDIR/oe-rootfs-repo/rpm
 200         fi
 201         echo "$DISTRO::$prj_name::$DISTRO_NAME::$DISTRO_VERSION" >> ${IMAGE_ROOTFS}/.target_build_list
 202     fi
 203 }
 204
 205 wrl_installer_get_count() {
 206     sum=0
 207     for i in $*; do
 208         sum=$(expr $sum + 1)
 209     done
 210     echo $sum
 211 }
 212
 213 wrl_installer[vardepsexclude] = "DATETIME"
 214 wrl_installer() {
 215     cat >${IMAGE_ROOTFS}/.discinfo <<_EOF
 216 ${DATETIME}
 217 ${DISTRO_NAME} ${DISTRO_VERSION}
 218 ${TARGET_ARCH}
 219 _EOF
 220
 221     : > ${IMAGE_ROOTFS}/.target_build_list
 222     counter=0
 223     targetimage_counter=0
 224     for target_build in ${INSTALLER_TARGET_BUILD}; do
 225         target_build="`readlink -f $target_build`"
 226         echo "Installer Target Build: $target_build"
 227         counter=$(expr $counter + 1)
 228         prj_name="`echo $target_build | sed -e 's#/ *$##g' -e 's#.*/##'`"
 229         prj_name="$prj_name-$counter"
 230
 231             # Generate .buildstamp
 232             if [ -n "${WRL_INSTALLER_CONF}" ]; then
 233                 installer_conf="`echo ${WRL_INSTALLER_CONF} | awk '{print $'"$counter"'}'`"
 234                 wrl_installer_copy_buildstamp $prj_name $installer_conf
 235             else
 236                 cat >${IMAGE_ROOTFS}/.buildstamp.$prj_name <<_EOF
 237 [Main]
 238 Product=${INSTPRODUCT}
 239 Version=${INSTVER}
 240 BugURL=${INSTBUGURL}
 241 IsFinal=True
 242 UUID=${DATETIME}.${TARGET_ARCH}
 243 _EOF
 244             fi
 245
 246             if [ -f "$target_build" ]; then
 247                 filename=$(basename "$target_build")
 248                 extension="${filename##*.}"
 249                 bpn=${BPN}
 250                 # Do not copy image for initramfs
 251                 if [ "${bpn##*initramfs}" != "${bpn%%initramfs*}" ]; then
 252                     continue
 253                 elif [ "x$extension" = "xext2" -o "x$extension" = "xext3" -o "x$extension" = "xext4" ]; then
 254                     echo "Image based target install selected."
 255                     mkdir -p "${IMAGE_ROOTFS}/LiveOS.$prj_name"
 256                     wrl_installer_hardlinktree "$target_build" "${IMAGE_ROOTFS}/LiveOS.$prj_name/rootfs.img"
 257                     echo "::$prj_name::" >> ${IMAGE_ROOTFS}/.target_build_list
 258                 else
 259                     bberror "Unsupported image: $target_build."
 260                     bberror "The image must be ext2, ext3 or ext4"
 261                     exit 1
 262                 fi
 263             elif [ -d "$target_build" ]; then
 264                 targetimage_counter=$(expr $targetimage_counter + 1)
 265                 target_image="`echo ${INSTALLER_TARGET_IMAGE} | awk '{print $'"$targetimage_counter"'}'`"
 266                 echo "Target Image: $target_image"
 267                 wrl_installer_copy_pkgs $target_build $target_image $prj_name $installer_conf
 268             else
 269                 bberror "Invalid configuration of INSTALLER_TARGET_BUILD: $target_build."
 270                 bberror "It must either point to an image (ext2, ext3 or ext4) or to the root of another build directory"
 271                 exit 1
 272             fi
 273
 274             ks_cfg="${INSTALLER_CONFDIR}/ks.cfg.$prj_name"
 275             if [ -n "${KICKSTART_FILE}" ]; then
 276                 ks_file="`echo ${KICKSTART_FILE} | awk '{print $'"$counter"'}'`"
 277                 bbnote "Copying kickstart file $ks_file to $ks_cfg ..."
 278                 mkdir -p ${INSTALLER_CONFDIR}
 279                 cp $ks_file $ks_cfg
 280             fi
 281             if [ -n "${KICKSTART_FILE_EXTRA}" ]; then
 282                 for ks_file in ${KICKSTART_FILE_EXTRA}; do
 283                     if [ -f $ks_file ]; then
 284                         cp $ks_file ${INSTALLER_CONFDIR}
 285                     else
 286                         bbwarn "The kickstart file $ks_file in KICKSTART_FILE_EXTRA doesn't exist!"
 287                     fi
 288                 done
 289             fi
 290     done
 291
 292     # Setup the symlink if only one target build dir.
 293     if [ "$counter" = "1" ]; then
 294         prj_name="`awk -F:: '{print $2}' ${IMAGE_ROOTFS}/.target_build_list`"
 295         entries=".buildstamp LiveOS Packages installer-config/ks.cfg"
 296         for i in $entries; do
 297             if [ -e ${IMAGE_ROOTFS}/$i.$prj_name ]; then
 298                 ln -sf `basename $i.$prj_name` ${IMAGE_ROOTFS}/$i
 299             fi
 300         done
 301     fi
 302 }
 303
 304 python __anonymous() {
 305     if "selinux" in d.getVar("DISTRO_FEATURES", True).split():
 306         raise bb.parse.SkipPackage("Unable to build the installer when selinux is enabled.")
 307
 308     if bb.data.inherits_class('image', d):
 309         if d.getVar("DISTRO", True) != "anaconda":
 310             raise bb.parse.SkipPackage("Set DISTRO = 'anaconda' in local.conf")
 311
 312         target_builds = d.getVar('INSTALLER_TARGET_BUILD', True)
 313         if not target_builds:
 314             errmsg = "No INSTALLER_TARGET_BUILD is found,\n"
 315             errmsg += "set INSTALLER_TARGET_BUILD = '<target-build-topdir>' and\n"
 316             errmsg += "INSTALLER_TARGET_IMAGE = '<target-image-pn>' to do RPMs\n"
 317             errmsg += "install, or\n"
 318             errmsg += "set INSTALLER_TARGET_BUILD = '<target-build-image>' to do\n"
 319             errmsg += "image copy install"
 320             raise bb.parse.SkipPackage(errmsg)
 321
 322         count = 0
 323         for target_build in target_builds.split():
 324             if not os.path.exists(target_build):
 325                 raise bb.parse.SkipPackage("The %s of INSTALLER_TARGET_BUILD does not exist" % target_build)
 326
 327             if os.path.isdir(target_build):
 328                 count += 1
 329
 330         # While do package management install
 331         if count > 0:
 332             target_images = d.getVar('INSTALLER_TARGET_IMAGE', True)
 333             if not target_images:
 334                 errmsg = "The INSTALLER_TARGET_BUILD is a dir, but not found INSTALLER_TARGET_IMAGE,\n"
 335                 errmsg += "set INSTALLER_TARGET_IMAGE = '<target-image-pn>' to do RPMs install"
 336                 raise bb.parse.SkipPackage(errmsg)
 337
 338             elif count != len(target_images.split()):
 339                 errmsg = "The INSTALLER_TARGET_BUILD has %s build dirs: %s\n" % (count, target_builds)
 340                 errmsg += "But INSTALLER_TARGET_IMAGE has %s build images: %s\n" % (len(target_images.split()), target_images)
 341                 raise bb.parse.SkipPackage(errmsg)
 342
 343         # The count of INSTALLER_TARGET_BUILD and WRL_INSTALLER_CONF must match when set.
 344         wrlinstaller_confs = d.getVar('WRL_INSTALLER_CONF', True)
 345         if wrlinstaller_confs:
 346             if len(wrlinstaller_confs.split()) != len(target_builds.split()):
 347                 raise bb.parse.SkipPackage("The count of INSTALLER_TARGET_BUILD and WRL_INSTALLER_CONF not match!")
 348             for wrlinstaller_conf in wrlinstaller_confs.split():
 349                 if not os.path.exists(wrlinstaller_conf):
 350                     raise bb.parse.SkipPackage("The installer conf %s in WRL_INSTALLER_CONF doesn't exist!" % wrlinstaller_conf)
 351
 352         # The count of INSTALLER_TARGET_BUILD and KICKSTART_FILE must match when set.
 353         kickstart_files = d.getVar('KICKSTART_FILE', True)
 354         if kickstart_files:
 355             if len(kickstart_files.split()) != len(target_builds.split()):
 356                 raise bb.parse.SkipPackage("The count of INSTALLER_TARGET_BUILD and KICKSTART_FILE not match!")
 357             for kickstart_file in kickstart_files.split():
 358                 if not os.path.exists(kickstart_file):
 359                     raise bb.parse.SkipPackage("The kickstart file %s in KICKSTART_FILE doesn't exist!" % kickstart_file)
 360
 361 }
 362
 363 python build_syslinux_cfg () {
 364     import copy
 365     import sys
 366
 367     workdir = d.getVar('WORKDIR')
 368     if not workdir:
 369         bb.error("WORKDIR not defined, unable to package")
 370         return
 371
 372     cfile = d.getVar('SYSLINUX_CFG')
 373     if not cfile:
 374         bb.fatal('Unable to read SYSLINUX_CFG')
 375 }