meta-starlingx/meta-stx-flock/stx-metal/platform-kickstarts.bb

   1 require metal-common.inc
   2 SUBPATH0 = "bsp-files/"
   3
   4 LICENSE = "Apache-2.0"
   5 LIC_FILES_CHKSUM = "file://kickstart/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
   6
   7 SRC_URI += " \
   8         file://kickstarts-adjustment-and-fixes-or-poky-stx.patch;striplevel=2 \
   9         file://kickstarts-add-setting-for-debain-style-networking.patch;striplevel=2 \
  10         "
  11
  12 PACKAGES += " \
  13         ${PN}-pxeboot \
  14         ${PN}-extracfgs \
  15         "
  16
  17 feed_dir = "/www/pages/feed/rel-${STX_REL}"
  18
  19 DEPENDS += "perl-native"
  20
  21 inherit deploy
  22
  23 do_unpack_append() {
  24     bb.build.exec_func('do_restore_files', d)
  25 }
  26
  27 do_restore_files() {
  28         cd ${S}
  29         git reset ${SRCREV} kickstart/LICENSE
  30         git checkout kickstart/LICENSE
  31 }
  32
  33 do_compile () {
  34         cd ${S}
  35         ./centos-ks-gen.pl --release ${STX_REL}
  36 }
  37
  38 do_install_prepend () {
  39         cd ${S}
  40         install -d -m 0755 ${D}${feed_dir}
  41         install -m 0444 generated/* ${D}${feed_dir}/
  42
  43         install -d -m 0755 ${D}/pxeboot
  44         install -D -m 0444 pxeboot/* ${D}/pxeboot
  45
  46         install -d -m 0755 ${D}/extra_cfgs
  47         install -D -m 0444 extra_cfgs/* ${D}/extra_cfgs
  48 }
  49
  50 do_deploy () {
  51         mkdir -p ${DEPLOYDIR}/stx-kickstarts
  52         cp -f ${S}/generated/* ${DEPLOYDIR}/stx-kickstarts
  53 }
  54
  55 addtask do_deploy after do_compile before do_build
  56
  57 FILES_${PN} = "${feed_dir}"
  58 FILES_${PN}-pxeboot = "/pxeboot"
  59 FILES_${PN}-extracfgs = "/extra_cfgs"