meta-oran/recipes-containers/kubernetes-plugins/flannel_0.11.0.bb

   1 #
   2 # Copyright (C) 2019 Wind River Systems, Inc.
   3 #
   4
   5 SUMMARY = "Flannel is a simple and easy way to configure a layer 3 network fabric designed for Kubernetes."
   6 DESCRIPTION = "\
   7   Flannel runs a small, single binary agent called flanneld on each host, \
   8   and is responsible for allocating a subnet lease to each host out of a \
   9   larger, preconfigured address space. Flannel uses either the Kubernetes \
  10   API or etcd directly to store the network configuration, the allocated \
  11   subnets, and any auxiliary data (such as the host's public IP). Packets \
  12   are forwarded using one of several backend mechanisms including VXLAN and \
  13   various cloud integrations. \
  14 "
  15 HOMEPAGE = "https://github.com/coreos/flannel"
  16
  17 LICENSE = "Apache-2.0"
  18 LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
  19
  20 SRC_URI = "\
  21     https://github.com/coreos/flannel/archive/v${PV}.tar.gz;downloadfilename=${BPN}-v${PV}.tar.gz \
  22     file://docker-img-flannel-v0.11.0.tar.bz2;unpack=0 \
  23 "
  24
  25 SRC_URI[md5sum] = "e023f76c688fd74dce6c0c8df8bea5d7"
  26 SRC_URI[sha256sum] = "476c886ddc06a8afcf54e181ac55579224c6be424089567a0b8d9e93dd08a053"
  27
  28 S = "${WORKDIR}/${BPN}-${PV}"
  29
  30 PACKAGES =+ "${PN}-img"
  31
  32 DOCKER_IMG = "/opt/docker_images/${BPN}"
  33 K8S_PLUGINS = "${sysconfdir}/kubernetes/plugins/${BPN}"
  34
  35 do_install() {
  36     install -d ${D}${K8S_PLUGINS}
  37     install -m 644 ${S}/README.md ${D}${K8S_PLUGINS}
  38     install -m 644 ${S}/Documentation/kube-flannel.yml ${D}${K8S_PLUGINS}
  39
  40     # Install the saved docker image
  41     install -d ${D}${DOCKER_IMG}
  42     install -m 644 ${WORKDIR}/docker-img-*.tar.bz2 ${D}${DOCKER_IMG}
  43 }
  44
  45 FILES_${PN}-img = "${DOCKER_IMG}"