m4/ax_check_compile_and_link_flag.m4

   1 # SYNOPSIS
   2 #
   3 #   AX_CHECK_COMPILE_AND_LINK_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
   4 #
   5 # DESCRIPTION
   6 #
   7 #   Check whether the given FLAG works with the current language's compiler
   8 #   or gives an error.  (Warnings, however, are ignored)
   9 #
  10 #   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
  11 #   success/failure.
  12 #
  13 #   If EXTRA-FLAGS is defined, it is added to the current language's default
  14 #   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
  15 #   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
  16 #   force the compiler to issue an error when a bad flag is given.
  17 #
  18 #   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
  19 #
  20 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
  21 #   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
  22 #
  23 # LICENSE
  24 #
  25 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  26 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  27 #   Copyright (c) 2017 Lev Walkin <vlm@lionet.info>
  28 #
  29 #   This program is free software: you can redistribute it and/or modify it
  30 #   under the terms of the GNU General Public License as published by the
  31 #   Free Software Foundation, either version 3 of the License, or (at your
  32 #   option) any later version.
  33 #
  34 #   This program is distributed in the hope that it will be useful, but
  35 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  36 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  37 #   Public License for more details.
  38 #
  39 #   You should have received a copy of the GNU General Public License along
  40 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  41 #
  42 #   As a special exception, the respective Autoconf Macro's copyright owner
  43 #   gives unlimited permission to copy, distribute and modify the configure
  44 #   scripts that are the output of Autoconf when processing the Macro. You
  45 #   need not follow the terms of the GNU General Public License when using
  46 #   or distributing such scripts, even though portions of the text of the
  47 #   Macro appear in them. The GNU General Public License (GPL) does govern
  48 #   all other use of the material that constitutes the Autoconf Macro.
  49 #
  50 #   This special exception to the GPL applies to versions of the Autoconf
  51 #   Macro released by the Autoconf Archive. When you make and distribute a
  52 #   modified version of the Autoconf Macro, you may extend this special
  53 #   exception to the GPL to apply to your modified version as well.
  54
  55 #serial 1
  56
  57 AC_DEFUN([AX_CHECK_COMPILE_AND_LINK_FLAG],
  58 [AC_PREREQ(2.61)dnl
  59 AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]clflags_$4_$1])dnl
  60 AC_CACHE_CHECK([whether _AC_LANG compiler and linker accept $1], CACHEVAR, [
  61   ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  62   _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
  63   AC_LINK_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
  64     [AS_VAR_SET(CACHEVAR,[yes])],
  65     [AS_VAR_SET(CACHEVAR,[no])])
  66   _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
  67 AS_IF([test x"AS_VAR_GET(CACHEVAR)" = xyes],
  68   [m4_default([$2], :)],
  69   [m4_default([$3], :)])
  70 AS_VAR_POPDEF([CACHEVAR])dnl
  71 ])dnl AX_CHECK_COMPILE_AND_LINK_FLAG
  72